AFormAut : SetResetFormAction メソッド

TOP > AFormAut > SetResetFormAction メソッド


 

説明

 

PDF 上の全てのフィールド、又は指定フィールドをリセットします。

以下の Acrobat ボタンのリセット・アクションを設定したのと同じことを行います。

 

AFormAut : SetResetFormAction メソッド

 

形式

 

void  SetResetFormAction  (
        LPCTSTR  bstrTrigger ,
        long  theFlags ,
        const  VARIANT&  arrFields ) ;

 

引数

 

  1. 第一引数 ( LPCTSTR  bstrTrigger ) :
    リセット・アクションのトリガを以下の文字列で指定します。 
      
    • up : マウスボタンを放す
    • down : マウスボタンを押す
    • enter : マウス・ポインタを範囲内に入れる
    • exit : マウス・ポインタを範囲外に出す  
        
  2. 第二引数 ( long  theFlags ) :
    0 : リセット対象のフィールド を第三引数に指定します。
    0以外 : リセット対象以外のフィールド を第三引数に指定します。 
     
  3. 第三引数 ( const  VARIANT&  arrFields ) :
    フィールド名を文字列で配列に入れて指定します。
    配列なので複数のフィールド名が指定できます。
    フィールド名は完全修飾名の形「aaa.xxx」、又は複数の子を持つ表現「bbb」を有する場合はそれらのすべてが対象になります。
    複数のフィールドが同じ名前を持っている場合は、すべてが対象になります。
    存在しないフィールド名は無視され、エラーにはなりません。
    省略時は全てのフィールドが対象になります。

 

戻り値

 

  • 無し。

 

動作するバージョン

 

Adobe
Acrobat
結果
備考
4
NO
Acrobat 4.0 ※Windows 98SE + Excel 2000 *1
※古いPDFのバージョンはOK!
5
NO
Acrobat 5.0.5 + Excel 2003 *1
※古いPDFのバージョンはOK
6
NO
Acrobat 6.0.6 Pro + Excel 2003 *1
※古いPDFのバージョンはOK
7
OK
Acrobat 7.1.4 Pro + Excel 2003 *2 
※レジストリ操作で全面的に可能になる
8
NO
Acrobat 8.3.1 Pro + Excel 2003
※当Acrobatバージョンでは全面的に不可
9
NO
Acrobat 9.5.5 Extended + Excel 2003
※当Acrobatバージョンでは全面的に不可
10
OK
Acrobat X (10.1.8) Extended + Excel 2003
11
OK
Acrobat XI (11.0.5) Extended + Excel 2003
  • OK : 正常処理。
  • NO : 動作しない。 又は実行時にエラーになる。
  • *1 : 「PDF のバージョン」によっては正常処理出来ない場合がある。
  • *2 : 全ての「PDF のバージョン」での処理を可能にしたければ、
    処理前のレジストリに以下を追加する必要があります。
    [HKEY_CURRENT_USER¥Software¥Adobe¥Adobe Acrobat¥7.0¥AVAlert]
    [HKEY_CURRENT_USER¥Software¥Adobe¥Adobe Acrobat¥7.0¥AVAlert¥cCheckbox]
    "idocNewerVersionWarning"=dword:00000001

 






サンプル:Excel のVBA

 

説明 : PDF上の指定フィールドのみをリセットするボタンを作成します。

AFormAut : SetResetFormAction メソッド リセット・ボタンを作成

 

Option Explicit

Public Const PDSaveFull = &H1
Public Const PDSaveLinearized = &H4
Public Const PDSaveCollectGarbage = &H20

Sub AFormAut_SetResetFormAction_test()

    Const CON_PDF_FILE = "D:¥work¥ReleaseNotes.pdf"
    Const CON_PDF_FI_S = "D:¥work¥ReleaseNotes-S.pdf"
    
    Dim lRet            As Long
    Dim strField(1)     As String
    
    'Acrobatオブジェクトの定義&作成
    Dim objAcroApp      As New Acrobat.AcroApp
    Dim objAcroAVDoc    As New Acrobat.AcroAVDoc
    Dim objAcroPDDoc    As Acrobat.AcroPDDoc
    Dim objAcroPDPage   As Acrobat.AcroPDPage
    Dim objAcroPoint    As Acrobat.AcroPoint
     
    Dim objAFormApp     As AFORMAUTLib.AFormApp
    Dim objAFormFields  As AFORMAUTLib.Fields
    Dim objAFormField   As AFORMAUTLib.Field
    
    '※CreateObject("AFormAut.App")のエラー
    '※[429 ActiveXコンポーネントはオブジェクトを作成できません。]
    '※回避用 / メモリにAcrobatを強制ロードさせる
    objAcroApp.CloseAllDocs
    
    '*―――――――――――――――――――--
    '* PDFファイルを開く
    
    '処理対象のPDFファイルを開く
    '※AVDocでOpenしないと"AFormAut.App"で実行エラー
    lRet = objAcroAVDoc.Open(CON_PDF_FILE, "")
    If lRet = 0 Then
        MsgBox "AVDocオブジェクトはOpen出来ません" & vbCrLf & _
            CON_PDF_FILE, vbOKOnly + vbCritical, "処理エラー"
        GoTo Skip_AFormAut_SetResetFormAction_test:
    End If
    
    'PDFページサイズを取得
    Set objAcroPDDoc = objAcroAVDoc.GetPDDoc
    Set objAcroPDPage = objAcroPDDoc.AcquirePage(0)
    Set objAcroPoint = objAcroPDPage.GetSize
   
    '*―――――――――――――――――――--
    '* AFormオブジェクトの作成
    
    Set objAFormApp = CreateObject("AFormAut.App")
    Set objAFormFields = objAFormApp.Fields
    
    '*―――――――――――――――――――--
    '* 印刷ボタンを追加 頁右上に配置

    Set objAFormField = objAFormFields.Add( _
        "Reset Button", "button", 0, _
        50, objAcroPoint.y - 20, 150, objAcroPoint.y - 60)
         
    strField(0) = "Text1"
    strField(1) = "Text2.sonota"    '無いので無視される
    
    With objAFormField
'        'フォントサイズ
'        .TextSize = 20
'        'ボタンのスタイル
        .BorderStyle = "beveled"    '浮き出し
'        'ボタンのキャプション
        .SetButtonCaption "N", "Reset"
'        '背景色
'        ' ※http://pdf-file.nnn2.com/?p=145
        .SetBackgroundColor "G", 0.85, 0.85, 0, 0
        .Highlight = "push"
        'リセットボタンを作成
        '.SetResetFormAction "up", 0
        .SetResetFormAction "up", 0, strField
    End With
    
    '設定後に開放
    Set objAFormField = Nothing
    
Skip_AFormAut_SetResetFormAction_test:

    '*―――――――――――――――――――--
    '* 終了処理
    
    '変更したPDFファイルの保存はPDDoc.Saveで必ず行う
    lRet = objAcroPDDoc.Save( _
        PDSaveFull + PDSaveCollectGarbage + PDSaveLinearized, _
        CON_PDF_FI_S)
    If lRet = 0 Then
        MsgBox "05: PDFファイルへ保存出来ませんでした" & vbCrLf & _
            CON_PDF_FI_S, vbOKOnly & vbCritical, "エラー"
    End If
    
    'AVDocを閉じる
    lRet = objAcroAVDoc.Close(1)
    
    'Acrobatアプリケーションの終了
    objAcroApp.Hide
    objAcroApp.Exit
    
    'オブジェクトの開放
    Set objAFormFields = Nothing
    Set objAFormApp = Nothing
    Set objAcroAVDoc = Nothing
    Set objAcroPDDoc = Nothing
    Set objAcroPDPage = Nothing
    Set objAcroPoint = Nothing
    Set objAcroApp = Nothing
    
    MsgBox "End Sub"

End Sub

※ソースコードHTML変換:SourceConverter

 


 

実行結果

 

1. Acrobat 7.1.4

 

  • リセット・ボタンの実行前
      
    AFormAut : SetResetFormAction メソッド 実行前
     
  • リセット・ボタンの実行後
    一番上の Text1.name フィールド名がリセットされた。
      
    AFormAut : SetResetFormAction メソッド 実行後 
     
  • 第二引数を 1 にすると、
    フィールドの2番目、3番目がリセットされます。
      
    AFormAut : SetResetFormAction メソッド 実行後(2)

 

2. Acrobat X (10.1.8)

 

Acrobat 7.1.4 と結果は同じ。

 

3. Acrobat XI (11.0.5)

 

Acrobat 7.1.4 と結果は同じ。

 

備考

 

  1. Acrobat JavaScript ( Acrobat 7.0 ) に相当する命令が resetForm です。

 

Adobe Web 解説 URL(英語)

 

 

その他の参考URL

 

  1. 【制限事項】Acrobat Forms API / OLE オートメーションメソッドの日本語対応について 
    http://kb2.adobe.com/jp/cps/511/511285.html   
      
  2. サンプル(英語) 
    http://www.vbforums.com/showthread.php?113838-Please-help-me-with-this-PDF-qeustion
     

 

戻る

コメントを残す

メールアドレスが公開されることはありません。 * が付いている欄は必須項目です

CAPTCHA


出来るだけ早く返答する様には心がけています。
が、遅くなる時もありますのでご了承ください。


SAMURAI Plugin

コメントをする時は出来れば以下もお願いします。

  • OS名 バージョン
  • Acrobat バージョン
  • ツール(Excel等) バージョン
コメントにサンプルコードを入れるとエラーになる場合が有ります。その時はコードの前後に <code> ・・・</code> タグを入れてください。

このサイトはスパムを低減するために Akismet を使っています。コメントデータの処理方法の詳細はこちらをご覧ください