AcroExch.Rect: Right プロパティ

TOP > AcroExch.Rect > Right      [...]


説明

PDF頁の右側のx-座標を得るか、または設定します。

 

形式

[get/set] Short

 

動作するバージョン

Version Adobe
Acrobat
備考
4
-
Acrobat 4.0    ※Windows 98SE + Excel 2000
5
-
Acrobat 5.0.5
6
-
Acrobat 6.0.3 Pro
7
-
Acrobat 7.0.9 Pro
Acrobat 7.1.4 Pro
8
OK
Acrobat 8.1.2 Pro
9
-
Acrobat 9.3.2 Extended
10
-
Acrobat X (10.1.8) Extended
11
-
Acrobat XI (11.0.04) Extended
  • OK = 動作する。
  • NO = 動作しない。 戻り値が0を返す。
  • - = 未確認。

 






サンプル:ExcelのVBA

 

  • F8キーでステップ実行しながら動作確認する。
  • 事前に参照設定をする。
  • Excel VBA開発環境に「イミディエイト ウインドウ」(Ctrl+G) と
    「ローカル ウインドウ」を表示しておくと動作確認がしやすいです。

 

Private Sub CommandButton22_Click()

    Dim objAcroApp      As New Acrobat.AcroApp
    Dim objAcroAVDoc    As New Acrobat.AcroAVDoc
    Dim objAcroPDDoc    As Acrobat.AcroPDDoc
    Dim objAcroPageView As Acrobat.AcroAVPageView
    Dim objAcroRect     As New Acrobat.AcroRect
    Dim objPDTextSelect As Acrobat.AcroPDTextSelect
    Dim lPageNumber     As Long '処理頁番号
    Dim lRet            As Long '戻り値
    Dim i               As Long '添え字
    Dim iEnd            As Long 'Loop終了値
  
    '初期設定
    lPageNumber = 9     '処理頁番号 ※0から
    
    'Acrobatアプリケーションを起動する。
    lRet = objAcroApp.Show
    'PDFファイルを開いて表示する。
    lRet = objAcroAVDoc.Open("E:¥save_as_xml.pdf", "")
    'PDDocオブジェクトを取得する
    Set objAcroPDDoc = objAcroAVDoc.GetPDDoc()
    'AVPageViewオブジェクトを取得する
    Set objAcroPageView = objAcroAVDoc.GetAVPageView()
    '指定ページ(10頁)に移動します。※0が開始頁
    lRet = objAcroPageView.GoTo(lPageNumber)
    
    '選択を示す長方形を作成する。頁左下部を起点。
    objAcroRect.Top = 400       '上
    objAcroRect.bottom = 100    '下
    objAcroRect.Right = 300     '右
    objAcroRect.Left = 100      '左
  
    'objAcroRectで指定された範囲を選択する。
    Set objPDTextSelect = _
        objAcroPDDoc.CreateTextSelect(lPageNumber, objAcroRect)
    
    '現在のテキスト選択としてそれを設定する。
    'そしてテキスト選択状態を画面表示する。
    lRet = objAcroAVDoc.SetTextSelection(objPDTextSelect)
    lRet = objAcroAVDoc.ShowTextSelect()
    
    '文字を配列単位で表示する。※改行コードも含む。
    Debug.Print "GetNumText()=(" & _
        objPDTextSelect.GetNumText() & ")"
    iEnd = objPDTextSelect.GetNumText() - 1
    For i = 0 To iEnd
        Debug.Print "GetText(" & i _
            & ")=(" & objPDTextSelect.GetText(i) & ")"
    Next
    
    'PDFファイルを保存しないで閉じます。
    lRet = objAcroAVDoc.Close(1)

    'Acrobatアプリケーションを終了する。
    lRet = objAcroApp.Hide
    lRet = objAcroApp.Exit

    'オブジェクトを強制開放する。
    Set objPDTextSelect = Nothing
    Set objAcroPageView = Nothing
    Set objAcroRect = Nothing
    Set objAcroPDDoc = Nothing
    Set objAcroAVDoc = Nothing
    Set objAcroApp = Nothing

End Sub

 

補足

  • 『Leftプロパティ値 < Rightプロパティ値』でないとこの後のSetTextSelectionメソッド実行時にエラーが発生します。
    Rightプロパティ設定時はチェックしていません。
  • OLEを行うとAcrobatが不安定になるので最後に一応オブジェクトを強制開放しています。
  • PDFの座標系はページの左下隅を基点としていますが、注釈の座標はページの左上隅を基点とします。

 

動作確認環境

  • WindowsXP Pro(+ SP3) +
    Acrobat 8.1.2 Pro + Office 2003 + MicrosoftUpdate

 

戻る

コメントを残す

メールアドレスが公開されることはありません。 * が付いている欄は必須項目です

CAPTCHA


出来るだけ早く返答する様には心がけています。
が、遅くなる時もありますのでご了承ください。


SAMURAI Plugin