AcroExch.Time: Year プロパティ

TOP > AcroExch.Time > Year      [...]


説明

AcroTimeオブジェクトからの年を得るか、又は設定します。

 

形式

[get/set] Short

 

設定又は戻り値

  • 1 から 32767 の年

 

動作するバージョン

Version Adobe
Acrobat
備考
4
-
Acrobat 4.0    ※Windows 98SE + Excel 2000
5
-

Acrobat 5.0.5
6
-

Acrobat 6.0.3 Pro
7
-
Acrobat 7.0.9 Pro
Acrobat 7.1.4 Pro
8
OK
Acrobat 8.1.2 Pro
9
-
Acrobat 9.3.2 Extended
10
-
Acrobat X (10.1.8) Extended
11
-
Acrobat XI (11.0.04) Extended
  • OK = 動作する。
  • NO = 動作しない。 戻り値が0を返す。
  • - = 未確認。

 






サンプル:ExcelのVBA

 

説明:

PDFファイルにあるテキスト注釈の年を全て2008年に統一します。

  • F8キーでステップ実行しながら動作確認する。
  • 事前に参照設定をする。

 

Sub AcroExch_Time_Year()

    Debug.Print "AcroExch_Time_Year:" & Now
    Dim objAcroApp          As New Acrobat.AcroApp
    Dim objAcroAVDoc        As New Acrobat.AcroAVDoc
    Dim objAcroPDDoc        As Acrobat.AcroPDDoc
    Dim objAcroPDPage       As Acrobat.AcroPDPage
    Dim objAcroPDAnnot      As Acrobat.AcroPDAnnot
    Dim objAcroTime         As Acrobat.AcroTime
    Dim objRect             As Acrobat.AcroRect
    Dim lRet                As Long     '戻り値
    Dim lPagesCnt           As Long     'ページ数
    Dim lAnnotsCnt          As Long     '注釈数
    Dim i                   As Long     '添え字
    Dim j                   As Long     '添え字
    Dim lTextCnt            As Long     '更新件数

    lTextCnt = 0
    'Acrobatを起動表示する
    lRet = objAcroApp.Show
    'PDFドキュメントを開いて表示する。
    lRet = objAcroAVDoc.Open("E:¥Test01.pdf", "")
    Set objAcroPDDoc = objAcroAVDoc.GetPDDoc()
    'PDFドキュメントのページ数を得る
    lPagesCnt = objAcroPDDoc.GetNumPages() - 1
    For i = 0 To lPagesCnt
        Set objAcroPDPage = objAcroPDDoc.AcquirePage(i)
        'ページに存在する注釈数を得る ★注意①
        lAnnotsCnt = objAcroPDPage.GetNumAnnots - 1
        For j = 0 To lAnnotsCnt
            Set objAcroPDAnnot = objAcroPDPage.GetAnnot(j)
            'Text注釈か?
            If objAcroPDAnnot.GetSubtype = "Text" Then
                'Text注釈の日時を取得
                Set objAcroTime = objAcroPDAnnot.GetDate
                '年を2008に設定
                objAcroTime.Year = 2008
                'Text注釈の日時を更新
                lRet = objAcroPDAnnot.SetDate(objAcroTime)
                lTextCnt = lTextCnt + 1
            End If
        Next j
    Next i
    Debug.Print "更新件数=" & lTextCnt
    
    'PDFファイルを保存して閉じる
    lRet = objAcroAVDoc.Close(0)

    'Acrobatを閉じる
    lRet = objAcroApp.Hide
    lRet = objAcroApp.Exit

    'オブジェクトを強制解放する
    Set objAcroTime = Nothing
    Set objAcroAVDoc = Nothing
    Set objAcroPDAnnot = Nothing
    Set objAcroPDPage = Nothing
    Set objAcroPDDoc = Nothing
    Set objAcroApp = Nothing

End  Sub

 

実行結果

  

TEST_Time_Year:2008/08/02 15:55:33
更新件数=3

 

補足

  • 「注意①」のGetNumAnnots メソッドは正常な値を返さない場合があります。

 


動作確認環境

  • WindowsXP Pro(+ SP3) +
    Acrobat 8.1.2 Pro + Office 2003 + MicrosoftUpdate

 

戻る

コメントを残す

メールアドレスが公開されることはありません。 * が付いている欄は必須項目です

CAPTCHA


出来るだけ早く返答する様には心がけています。
が、遅くなる時もありますのでご了承ください。


SAMURAI Plugin

コメントをする時は出来れば以下もお願いします。

  • OS名 バージョン
  • Acrobat バージョン
  • ツール(Excel等) バージョン
コメントにサンプルコードを入れるとエラーになる場合が有ります。その時はコードの前後に <code> ・・・</code> タグを入れてください。

This site uses Akismet to reduce spam. Learn how your comment data is processed.