HiliteList

AcroExch.HiliteList： Add メソッド

2020年3月15日管理人 10件のコメント

TOP > AcroExCh.HiliteList > Add [...]

説明

PDFテキスト上の開始位置と個数の情報を持った引数(オブジェクト)を作成します。

この引数(オブジェクト)を特別にハイライトリストと言います。

「テキストをハイライト表示」とは全く関係ありません。※備考も参照。

このハイライトリストは PDPageオブジェクトの CreatePageHiliteメソッドか CreateWordHiliteメソッドを使用する時だけの引数に使うものです。

形式

VARIANT_BOOL Add(short nOffset, short nLength);

引数

第１引数(short nOffset)：
文字、文字列、又は単語単位を位置指定する場所。0を開始位置とする。
第２引数(short nLength)：
第１引数から数えての個数。１以上を指定。
０を指定すると予期しない結果になります。

戻り値

-1 ：成功
0 ：失敗

動作するバージョン

Version	Adobe Acrobat	備考
4	OK	Acrobat 4.0 ※Windows 98SE + Excel 2000
5	OK	Acrobat 5.0.5
6	OK	Acrobat 6.0.3 Pro
7	NO	Acrobat 7.1.4 Pro
8	NO	Acrobat 8.1.2 Pro Acrobat 8.2.3 Pro
9	OK	Acrobat 9.3.3 Extended
10	-	Acrobat X (10.1.8) Extended
11	-	Acrobat XI (11.0.04) Extended

OK = 動作する。
NO = 動作しない。戻り値が0を返す。
- = 未確認。

サンプル：Excel のVBA

説明： PDFドキュメントの文字列を抽出する。

F8キーでステップ実行しながら動作確認する。
事前に参照設定をする。

001 Sub AcroExch_HiliteList_Add()
002 
003     'Acrobatオブジェクトの定義＆作成
004     'Acrobat 4,5,6 の時
005 '    Dim objAcroApp          As Acrobat.CAcroApp
006 '    Dim objAcroAVDoc        As Acrobat.CAcroAVDoc
007 '    Dim objAcroHiliteList   As Acrobat.CAcroHiliteList
008 '    Dim objAcroPDDoc        As Acrobat.CAcroPDDoc
009 '    Dim objAcroPDPage       As Acrobat.CAcroPDPage
010 '    Dim objAcroAVPageView   As Acrobat.CAcroAVPageView
011 '    Dim objAcroPDTextSelect As Acrobat.CAcroPDTextSelect
012 '    Set objAcroApp = CreateObject("AcroExch.App")
013 '    Set objAcroAVDoc = CreateObject("AcroExch.AVDoc")
014 '    Set objAcroHiliteList = CreateObject("AcroExch.HiliteList")
015 '    Set objAcroPDDoc = CreateObject("AcroExch.PDDoc")
016      
017     'Acrobat 7,8,9,10,11 の時
018     Dim objAcroApp          As New Acrobat.AcroApp
019     Dim objAcroAVDoc        As New Acrobat.AcroAVDoc
020     Dim objAcroHiliteList   As New Acrobat.AcroHiliteList
021     Dim objAcroPDDoc        As New Acrobat.AcroPDDoc
022     Dim objAcroPDPage       As Acrobat.AcroPDPage
023     Dim objAcroAVPageView   As Acrobat.AcroAVPageView
024     Dim objAcroPDTextSelect As Acrobat.AcroPDTextSelect
025      
026     '以降はAcrobat全て共通
027     Dim lRet                As Long '戻り値
028     Dim i                   As Long '添え字
029     Dim j                   As Long '添え字
030     Dim lPages              As Long 'ページ番号
031     Dim lCnt                As Long 'カウント
032     Dim strText             As String   '文字列
033     Dim lFileNo             As Long 'ファイル番号
034      
035     Const CON_PDF = "C:\work\Test01.pdf"
036     Const CON_LOG_FILE = "C:\work\LOG01.txt"
037 
038     'PDFファイルを開く
039     lRet = objAcroPDDoc.Open(CON_PDF)
040     Set objAcroAVDoc = objAcroPDDoc.OpenAVDoc(CON_PDF)
041     '画面にPDFを表示する
042     lRet = objAcroAVDoc.Open(CON_PDF, "")     '(注１)
043     Set objAcroAVPageView = objAcroAVDoc.GetAVPageView
044     Set objAcroPDDoc = objAcroAVDoc.GetPDDoc()
045     'Acrobatを起動表示する
046     lRet = objAcroApp.Show  '(注１)
047     'ハイライトリストを作成する。※ページ中の単語数
048     lRet = objAcroHiliteList.Add(0, 32767)
049  
050     '開いたPDFドキョメントの全ページ数を取得する
051     lPages = objAcroPDDoc.GetNumPages() - 1
052      
053     '結果をテキストファイルに書き出す
054     lFileNo = FreeFile()
055     Open CON_LOG_FILE For Output Access Write As lFileNo
056     Print #lFileNo, "(" & CON_PDF & ") file 総Page数=" & _
057         lPages + 1 & " Start=" & Now()
058      
059     For i = 0 To lPages
060         'ページ単位のPDPageオブジェクトを作成する
061         Set objAcroPDPage = objAcroPDDoc.AcquirePage(i)
062         'ハイライトリスト(objAcroHiliteList)からページ単位の
063         'テキスト選択のPDTextSelectオブジェクトを作成する
064         Set objAcroPDTextSelect = _
065             objAcroPDPage.CreatePageHilite(objAcroHiliteList)
066         '抽出した文字列の数(Index)を取得する
067         lCnt = objAcroPDTextSelect.GetNumText() - 1
068         strText = ""
069         For j = 0 To lCnt
070             '単語単位で抽出する
071             strText = strText & _
072                         objAcroPDTextSelect.GetText(j)
073 '            Debug.Print strText
074         Next j
075          
076         '一頁分をテキストファイルに出力する
077         Print #lFileNo, "**** Page(" & i + 1 & ")=" & _
078             " PageWordCnt=" & lCnt & " ****" & vbCrLf & strText
079      
080     Next i
081  
082     Print #lFileNo, "End " & Now()
083     'テキストファイルを閉じる
084     Close #lFileNo
085 
086     'PDFファイルを保存しないで閉じる
087     objAcroPDDoc.Close
088     'Acrobatを閉じる
089     lRet = objAcroApp.Hide      '(注１)
090     lRet = objAcroApp.Exit
091      
092     'オブジェクトを強制解放する
093     Set objAcroPDTextSelect = Nothing
094     Set objAcroPDPage = Nothing
095     Set objAcroPDDoc = Nothing
096     Set objAcroAVDoc = Nothing
097     Set objAcroPDTextSelect = Nothing
098     Set objAcroAVPageView = Nothing
099     Set objAcroApp = Nothing
100 
101 End Sub

　Highlight：プログラミング言語のソースコードを構文で色分け (GUI編)
　

実行結果

PDFファイル(Test01.pdf)のPDFバージョンは「1.3」を使用しました。

▼ Acrobat v4.0 の実行結果

上が実行結果のテキストファイルをワードパットで開いた結果。

下が読み込んだPDFファイル。

「版版版版Adobe 」と表示されているが、元のPDFもクリップボードにコピーすると同じ結果「版版版版Adobe 」になる。

これはAcrobat v4 のバグと考えられる。

▼ Acrobat v5.0 の実行結果

Acrobat v4 と同じPDFファイルを読み込んでいます。

「版」は正常に読み込んでいます。

▼ Acrobat v6.0 の実行結果

Acrobat v4 と同じPDFファイルを読み込んでいます。

「版」は正常に読み込んでいます。

Acrobat v5 と結果は同じです。

▼ Acrobat v7.1.4 の実行結果

Addメソッドを実行するとVBAが出して異常終了してしまう。

備考の６を参照。

▼ Acrobat v8.2.3 の実行結果

Addメソッドを実行するとVBAが出して異常終了してしまう。

備考の６を参照。

(但し、既に環境は無いが、Acrobat v8.1.2 では動作確認が出来ていた。※<- 過去の記録)

▼ Acrobat v9.0 の実行結果

Acrobat v4 と同じPDFファイルを読み込んでいます。

「版」は正常に読み込んでいます。

Acrobat v5 と結果は同じです。

補足

実行結果から、Acrobat v4 ,Acrobat v7 と Acrobat v8 では使用しない方がいいです。
(注１)は特に必要ありません。テスト確認用のロジックです。
①はコメントにしても実行結果には影響しません。
ここで言っている「ハイライトリスト」は「テキストをハイライト表示」する事とは異なる事に注意して下さい。
選択範囲の開始位置と個数の情報を持った引数(オブジェクト)を作るだけ、と思って下さい。
このメソッド実行時にPDFドキュメントに変化も影響も全くありません。
PDPageオブジェクトの CreatePageHiliteメソッドか CreateWordHiliteメソッドを使用した時に、このAddメソッドの意味が理解できます。
上記サンプルは以下のURLを参考にしました。
~~http://homepage3.nifty.com/belie/vba/vba017.htm~~
Acrobat v7.1.4 , v8.2.3 + Excel 2003 でAddメソッドを実行すると以下のメッセージをVBAが出して異常終了します。

注意事項

Acrobat v4 でPDTextSelectオブジェクトに連携する時に２バイト文字(日本語)の抽出(GetTextメソッド)で異常抽出が発生する場合があります。
結果から見るとAcrobat v4 のバグと判断できます。
例：
画面表示例： Windows 版Adobe Acrobat 4.0 ReadMe
PDF元：Windows 版版版版Adobe Acrobat 4.0 ReadMe
抽出結果：Windows 版版版版Adobe Acrobat 4.0 ReadMe
これはAcrobat v4 アプリケーション本体の問題と思われます。
再度、このAddメソッドを実行する時は一旦
Set objAcroHiliteList = Nothing
Set objAcroHiliteList = CreateObject("AcroExch.HiliteList")
でAcroHiliteListオブジェクトを再作成する必要があります。
そうしないとAddメソッドは有効になりません。Addメソッドは上書きはしません。
Acrobat v7.1.4 , v8.2.3 + Excel 2003 でAddメソッド使用時にVBAが異常終了します。
しかし、Acrobat v8に関しては旧バージョンでは動作した過去実績が有ります。
それを考えると、アップデートによって使えなくなった可能性があります。これはちょっと変です。
実行結果から、PDFをテキストファイルに落とすと、改行は見た目の位置で改行します。
しかし、別の(英語)PDFをテキストファイルに落とすと、PDF内部で持っている位置で改行します。つまり見た目とは異なります。
PDFファイルの作り方により異なるみたいです。（再調査要）

動作確認環境

Windows98SE( + WindowsUpdate)
+ Acrobat 4.0 + Office 2000
WindowsXP Pro( + SP3 + WindowsUpdate)
+ Acrobat 5.0.5 + Office 2003( + SP3)
WindowsXP Pro( + SP3 + WindowsUpdate)
+ Acrobat 6.0.3 Pro + Office 2003( + SP3)
WindowsXP Pro( + SP3 + WindowsUpdate)
+ Acrobat 7.1.4 Pro + Office 2003( + SP3)
WindowsXP Pro( + SP3 + WindowsUpdate)
+ Acrobat 8.1.2 Pro + Office 2003( + SP3)
WindowsXP Pro( + SP3 + WindowsUpdate)
+ Acrobat 8.2.3 Pro + Office 2003( + SP3)
WindowsXP Pro( + SP3 + WindowsUpdate)
+ Acrobat 9.3.3 Extended + Office 2003( + SP3)

Adobe Web 解説 URL(英語) v9.1

~~http://livedocs.adobe.com/acrobat_sdk/9/Acrobat9_HTMLHelp/IAC_API_OLE_Objects.103.75.html~~

＜戻る＞