AFormAut : BorderStyle プロパティ

TOP > AFormAut > BorderStyle プロパティ


説明

フィールドの境界線スタイルを設定します。

指定できる境界線スタイルは以下の5つです。

  • solid : 周囲を実線で表示
  • beveled : ベベル。境界線の内側に浮き出た外観を加える
  • dashed : 周囲を破線で表示
  • inset : 切り込み。境界線の内側にくぼんだ外観を加える
  • underline : 底辺に下線を描く

AFormAut : BorderStyle プロパティ ※ボタン・スタイルの例  

 

 

形式

[ 取得 / 設定 ] String

 

 

設定又は戻り値

設定、又は取得可能な文字列

  1. solid : 周囲を実線で表示
  2. beveled : ベベル。境界線の内側に浮き出た外観を加える
  3. dashed : 周囲を破線で表示
  4. inset : 切り込み。境界線の内側にくぼんだ外観を加える
  5. underline : 底辺に下線を描く

上記以外の値を設定しようとすると、実行エラーが発生します。

AFormAut : BorderStyle プロパティ 値の不正時

Microsoft Visual Basic
実行エラー '5':
プロシージャの呼び出し、または引数が不正です。
終了 デバッグ ヘルプ

 

    

動作するバージョン

Adobe
Acrobat
結果
備考
4
NO
Acrobat 4.0 ※Windows 98SE + Excel 2000 *1
※古いPDFのバージョンはOK!
5
NO
Acrobat 5.0.5 + Excel 2003 *1
※古いPDFのバージョンはOK
6
NO
Acrobat 6.0.6 Pro + Excel 2003 *1
※古いPDFのバージョンはOK
7
OK
Acrobat 7.1.4 Pro + Excel 2003 *2 
※レジストリ操作で全面的に可能になる
8
NO
Acrobat 8.3.1 Pro + Excel 2003
※当Acrobatバージョンでは全面的に不可
9
NO
Acrobat 9.5.5 Extended + Excel 2003
※当Acrobatバージョンでは全面的に不可
10
OK
Acrobat X (10.1.8) Extended + Excel 2003
11
OK
Acrobat XI (11.0.5) Extended + Excel 2003
  • OK : 正常処理。
  • NO : 動作しない。 又は実行時にエラーになる。
  • *1 : 「PDF のバージョン」によっては正常処理出来ない場合がある。
  • *2 : 全ての「PDF のバージョン」での処理を可能にしたければ、
    処理前のレジストリに以下を追加する必要があります。
    [HKEY_CURRENT_USER¥Software¥Adobe¥Adobe Acrobat¥7.0¥AVAlert]
    [HKEY_CURRENT_USER¥Software¥Adobe¥Adobe Acrobat¥7.0¥AVAlert¥cCheckbox]
    "idocNewerVersionWarning"=dword:00000001

 






サンプル:Excel のVBA

 

説明 : PDF上のボタンのスタイルを変更します。

AFormAut : BorderStyle プロパティ

 

Option Explicit

Public Const PDSaveFull = &H1
Public Const PDSaveLinearized = &H4
Public Const PDSaveCollectGarbage = &H20

Sub AFormAut_BorderStyle_test()

    Const CON_PDF_FILE = "D:¥work¥ReleaseNotes.pdf"
    Const CON_PDF_FI_S = "D:¥work¥ReleaseNotes-S.pdf"
    
    Dim lRet            As Long
    
    'Acrobatオブジェクトの定義&作成
    Dim objAcroApp      As New Acrobat.AcroApp
    Dim objAcroAVDoc    As New Acrobat.AcroAVDoc
    Dim objAcroPDDoc    As Acrobat.AcroPDDoc
     
    Dim objAFormApp     As AFORMAUTLib.AFormApp
    Dim objAFormFields  As AFORMAUTLib.Fields
    Dim objAFormField   As AFORMAUTLib.Field
    
    '※CreateObject("AFormAut.App")のエラー
    '※[429 ActiveXコンポーネントはオブジェクトを作成できません。]
    '※回避用 / メモリにAcrobatを強制ロードさせる
    objAcroApp.CloseAllDocs
    
    '*―――――――――――――――――――--
    '* PDFファイルを開く
    
    '処理対象のPDFファイルを開く
    '※AVDocでOpenしないと"AFormAut.App"で実行エラー
    lRet = objAcroAVDoc.Open(CON_PDF_FILE, "")
    If lRet = 0 Then
        MsgBox "AVDocオブジェクトはOpen出来ません" & vbCrLf & _
            CON_PDF_FILE, vbOKOnly + vbCritical, "処理エラー"
        GoTo Skip_AFormAut_BorderStyle_test:
    End If
    
    '*―――――――――――――――――――--
    '* AFormオブジェクトの作成
    
    Set objAFormApp = CreateObject("AFormAut.App")
    Set objAFormFields = objAFormApp.Fields
    
    '*―――――――――――――――――――--
    '* ボタンをスタイルを変更する。
    
    Set objAFormField = objAFormFields.Item("filed.bt1")
    objAFormField.BorderStyle = "solid"
    objAFormField.SetButtonCaption "N", objAFormField.BorderStyle
    
    Set objAFormField = objAFormFields.Item("filed.bt2")
    objAFormField.BorderStyle = "dashed"
    objAFormField.SetButtonCaption "N", objAFormField.BorderStyle
    
    Set objAFormField = objAFormFields.Item("filed.bt3")
    objAFormField.BorderStyle = "beveled"
    objAFormField.SetButtonCaption "N", objAFormField.BorderStyle
    
    Set objAFormField = objAFormFields.Item("filed.bt4")
    objAFormField.BorderStyle = "inset"
    objAFormField.SetButtonCaption "N", objAFormField.BorderStyle
    
    Set objAFormField = objAFormFields.Item("filed.bt5")
    objAFormField.BorderStyle = "underline"
    objAFormField.SetButtonCaption "N", objAFormField.BorderStyle
    
Skip_AFormAut_BorderStyle_test:

    '*―――――――――――――――――――--
    '* 終了処理
    
    '変更したPDFファイルの保存はPDDoc.Saveで必ず行う
    Set objAcroPDDoc = objAcroAVDoc.GetPDDoc
    lRet = objAcroPDDoc.Save( _
        PDSaveFull + PDSaveCollectGarbage + PDSaveLinearized, _
        CON_PDF_FI_S)
    If lRet = 0 Then
        MsgBox "05: PDFファイルへ保存出来ませんでした" & vbCrLf & _
            CON_PDF_FI_S, vbOKOnly & vbCritical, "エラー"
    End If
    
    'AVDocを閉じる
    lRet = objAcroAVDoc.Close(1)
    
    'Acrobatアプリケーションの終了
    objAcroApp.Hide
    objAcroApp.Exit
    
    'オブジェクトの開放
    Set objAFormFields = Nothing
    Set objAFormApp = Nothing
    Set objAcroAVDoc = Nothing
    Set objAcroPDDoc = Nothing
    Set objAcroApp = Nothing
    
    MsgBox "End Sub"

End Sub

※ソースコードHTML変換:SourceConverter

 

 

 


実行結果

 

1. Acrobat 7.1.4

 

AFormAut : BorderStyle プロパティ 実行前と実行後
    
   

2. Acrobat X (10.1.8)

Acrobat 7.1.4 と結果は同じ。

 

3. Acrobat XI (11.0.5)

Acrobat 7.1.4 と結果は同じ。

 

 

備考

  1. 上記サンプルでは、フィールド名は完全修飾(フル名称)で指定しています。
    しかし、xxx.yyy の様にピリオドで区切ってあるフィールド名が複数ある時は、xxx だけを指定すれば頭に xxx. がつく全てのフイールド名が対象になります。
      
    例 : 頭に「field.」のフィールド名がつくのはベベルに設定されます。
         Set objAFormField = objAFormFields.Item("filed")
        objAFormField.BorderStyle = "beveled"
      
  2. Acrobat JavaScript ( Acrobat 8.0 ) に相当する命令が BorderStyle です。

 

Adobe Web 解説 URL(英語)

 

その他の参考URL

  1. JavaScript for Acrobat API Reference Adobe Acrobat SDK バージョン 8.0 のBorderStyle を参照
    ※Acrobat JavaScript の詳細な解説書 / Acrobat v8.0 リファレンス(765頁) 
           

 

 

戻る

コメントを残す

メールアドレスが公開されることはありません。 * が付いている欄は必須項目です

CAPTCHA


出来るだけ早く返答する様には心がけています。
が、遅くなる時もありますのでご了承ください。


SAMURAI Plugin

コメントをする時は最低でも以下をお願いします。

  • OS名 バージョン
  • Acrobat バージョン
  • ツール(Excel等) バージョン