AFormAut : ExportAsHtml メソッド

TOP > AFormAut > ExportAsHtml メソッド


説明

PDFファイルのフォームデータの情報のみを、URLエンコード形式で変換してファイル出力します。

AFormAut : ExportAsHtml メソッド

 

注釈データは抽出しない。

下記のWEBブラウザのURLの?の後の引数の様な形式で、フィールド情報のみをファイルへ抽出します。

AFormAut : ExportAsHtml メソッド

 

形式

void  ExportAsHtml (
        LPCTSTR  bstrFullPath ,
        LPCTSTR  bstrSubmitButton ,
        BOOL  bEmptyFields ,
        const  VARIANT&  arrFields ) ;

  

引数

  1. 第一引数 ( LPCTSTR  bstrFullPath ) : 
    作成するファイルのフルパス名。 
    但し、拡張子はなんでも良い。 .txt でも良い。
     
  2. 第二引数 ( LPCTSTR  bstrSubmitButton ) :
    Button型の既存のフォームフィールドの名前。
    省略(空文字)も可。 
    ※これに関する英語原文の内容がココ
      
  3. 第三引数 ( BOOL  bEmptyFields ) : 
    True : 値の持たないフィールドもファイルの作成時に含める
    False : 含めない
     
  4. 第四引数 ( const  VARIANT&  arrFields ) : 
    ファイルに含めるフィールドの完全修飾名を表す文字列の配列。
    この配列に、全ての子のフィールドがHTML ファイルに含まれるようにするには、
    非終端フィールド「. ピリオド」の名前が含まれている必要が有ります。
    オプションなので省略可能。 省略時は全てが対象になります。
    例:サブツリー全体を簡単に書き出す方法が指定出来ます。
    arrFields パラメータの一部として「name」を入れると、「name.title」、「name.first」、「name.middle」、「name.last」などのフィールドが書き出されます。
    この場合「name-title」等は対象から外れます。

 

戻り値

  • 無し。

 

動作するバージョン

Adobe
Acrobat
結果
備考
4
NO
Acrobat 4.0 ※Windows 98SE + Excel 2000 *1
※古いPDFのバージョンはOK!
5
NO
Acrobat 5.0.5 + Excel 2003 *1
※古いPDFのバージョンはOK
6
NO
Acrobat 6.0.6 Pro + Excel 2003 *1
※古いPDFのバージョンはOK
7
OK
Acrobat 7.1.4 Pro + Excel 2003 *2 
※レジストリ操作で全面的に可能になる
8
NO
Acrobat 8.3.1 Pro + Excel 2003
※当Acrobatバージョンでは全面的に不可
9
NO
Acrobat 9.5.5 Extended + Excel 2003
※当Acrobatバージョンでは全面的に不可
10
OK
Acrobat X (10.1.8) Extended + Excel 2003
11
OK
Acrobat XI (11.0.5) Extended + Excel 2003
  • OK : 正常処理。
  • NO : 動作しない。 又は実行時にエラーになる。
  • *1 : 「PDF のバージョン」によっては正常処理出来ない場合がある。
  • *2 : 処理前のレジストリに以下を追加する必要があります。
    [HKEY_CURRENT_USER¥Software¥Adobe¥Adobe Acrobat¥7.0¥AVAlert]
    [HKEY_CURRENT_USER¥Software¥Adobe¥Adobe Acrobat¥7.0¥AVAlert¥cCheckbox]
    "idocNewerVersionWarning"=dword:00000001
     

 






サンプル:Excel のVBA

 

説明 : PDFファイル上のフォームデータの情報のみを、URLエンコード形式で変換してファイル出力します。

   

3つのフィールド名: [ Text1.name ]  [ Text1email ]  [ URL ] の

値 [ 1234 ] , [ AABB ] , [ 情報です ] をURLエンコード形式で変換して、ファイル出力します。

 

AFormAut : ExportAsHtml  フィールド名AFormAut : ExportAsHtml  フィールドの値

    

Option Explicit

Sub AFormAut_ExportAsHtml_test()

    Dim arrFields(1)    As String
    Dim lRet            As Long
    
    Const CON_PDF_FILE = "D:¥work¥save_as_xml.pdf"
    Const CON_FDF_FILE = "D:¥work¥save_as_xml.txt"
    
    'Acrobatオブジェクトの定義&作成
    Dim objAcroApp      As New Acrobat.AcroApp
    Dim objAcroAVDoc    As New Acrobat.AcroAVDoc
     
    Dim objAFormApp     As AFORMAUTLib.AFormApp
    Dim objAFormFields  As AFORMAUTLib.Fields
    
    '※CreateObject("AFormAut.App")のエラー
    '※[429 ActiveXコンポーネントはオブジェクトを作成できません。]
    '※回避用 / メモリにAcrobatを強制ロードさせる
    objAcroApp.CloseAllDocs
    
    '*―――――――――――――――――――--
    '* PDFファイルを開く
    
    '処理対象のPDFファイルを開く
    '※AVDocでOpenしないと"AFormAut.App"で実行エラー
    lRet = objAcroAVDoc.Open(CON_PDF_FILE, "")
    If lRet = 0 Then
        MsgBox "AVDocオブジェクトはOpen出来ません" & vbCrLf & _
            CON_PDF_FILE, vbOKOnly + vbCritical, "処理エラー"
        GoTo Skip_AFormAut_ExportAsHtml_test:
    End If
    
    '*―――――――――――――――――――--
    '* AFormオブジェクトの作成
    
    Set objAFormApp = CreateObject("AFormAut.App")
    Set objAFormFields = objAFormApp.Fields
    
    '*―――――――――――――――――――--
    '* FDFの作成
    
    arrFields(0) = "Text1"
    arrFields(1) = "Text2" '該当するフィールド無し
    
    objAFormFields.ExportAsHtml CON_FDF_FILE, "", True, arrFields
    
Skip_AFormAut_ExportAsHtml_test:

    '*―――――――――――――――――――--
    '* 終了処理
    
    '変更しないで閉じます
    lRet = objAcroAVDoc.Close(1)
    
    'Acrobatアプリケーションの終了
    objAcroApp.Hide
    objAcroApp.Exit
    
    'オブジェクトの開放
    Set objAFormFields = Nothing
    Set objAFormApp = Nothing
    Set objAcroAVDoc = Nothing
    Set objAcroApp = Nothing
    
    MsgBox "End Sub "

End Sub

 

 

 


実行結果

 

1. Acrobat 7.1.4

  1. 第四引数の指定無し:
    全てのフィールドが正常に正常に抽出される。
    AFormAut : ExportAsHtml メソッド Acrobat 7 実行結果
    Text1.name=1234&Text1email=AABB&URL=%8f%ee%95%f1%82%c5%82%b7
      
  2. 第四引数の指定有り ( 配列 : "Text1" ) :
    該当するフィール情報が正常に抽出される。
    AFormAut : ExportAsHtml メソッド Acrobat 7 実行結果
    Text1.name=1234
     

 

2. Acrobat X (10.1.8)

Acrobat 7.1.4 と同じ。

 

3. Acrobat XI (11.0.5)

Acrobat 7.1.4 と同じ。

 

  

備考

  1. 注釈データは抽出されない。

 

Adobe Web 解説 URL(英語)

 

戻る

コメントを残す

メールアドレスが公開されることはありません。 * が付いている欄は必須項目です

CAPTCHA


出来るだけ早く返答する様には心がけています。
が、遅くなる時もありますのでご了承ください。


SAMURAI Plugin

コメントをする時は最低でも以下をお願いします。

  • OS名 バージョン
  • Acrobat バージョン
  • ツール(Excel等) バージョン