AFormAut : Field.TextFont プロパティ

TOP > AFormAut > AFormAut : Field.TextFont プロパティ


説明

テキストフィールド、コンボボックス、リストボックス、またはボタンに配置するテキストのフォントを示します。

 

形式

[ 取得 / 設定 ] String

 

設定又は戻り値

設定、又は取得可能なフォント

  1. HeiseiMin-W3-UniJIS-UCS2-H (平成明朝)
  2. HeiseiKakuGo-W5-UniJIS-UCS2-H (平成角ゴシック)
  3. Courier
  4. Courier-Bold
  5. Courier-Oblique
  6. Courier-BoldOblique
  7. Helvetica
  8. Helvetica-Bold
  9. Helvetica-Oblique
  10. Helvetica-BoldOblique
  11. Symbol
  12. Times-Roman
  13. Times-Bold
  14. Times-Italic
  15. Times-BoldItalic
  16. ZapfDingbats

フォーム機能で使用可能な日本語フォントは、平成明朝、平成角ゴシック のみです。

"平成明朝" では無く "HeiseiMin-W3-UniJIS-UCS2-H" と指定します。

 

動作するバージョン

Adobe
Acrobat
  結果
備考
4
Acrobat 4.0 ※Windows 98SE + Excel 2000 *1
5
Acrobat 5.0.5 + Excel 2003 *1
6
Acrobat 6.0.6 Pro + Excel 2003 *1
7
OK
Acrobat 7.1.4 Pro + Excel 2003 *2
8
NO
Acrobat 8.3.1 Pro + Excel 2003
※当Acrobatバージョンでは全面的に不可
9
NO
Acrobat 9.5.2 Extended + Excel 2003
※当Acrobatバージョンでは全面的に不可
10
OK
Acrobat X (10.1.4) Extended + Excel 2003
11
OK
Acrobat XI (10.0) Extended + Excel 2003
  • OK : 正常処理する。
  • NO : 動作しない。 又は実行時にエラーになる。
  • *1 : 「PDF のバージョン」によっては正常処理出来ない場合がある。
    詳細は下の 注意 を参照ください。
  • *2 : 処理前のレジストリに以下を追加する必要があります。
    [HKEY_CURRENT_USER¥Software¥Adobe¥Adobe Acrobat¥7.0¥AVAlert]
    [HKEY_CURRENT_USER¥Software¥Adobe¥Adobe Acrobat¥7.0¥AVAlert¥cCheckbox]
    "idocNewerVersionWarning"=dword:00000001

 






サンプル:ExcelのVBA

 

  1. 説明:PDFファイルの各ページにヘッダーを追加する。
  2. F8キーでステップ実行しながら動作確認します。
  3. 事前に 参照設定(AFormAutの追加版) が必要です。

 

Option Explicit

Sub AFormAut_Field_TextFont()
On Error GoTo Err_AFormAut_Field_TextFont:

    Dim i               As Integer
    Dim iPageNum        As Integer
    Dim bRet            As Boolean
    Dim bEnd            As Boolean
    Dim sFilePath_new   As String
    Dim objAFormApp     As AFORMAUTLib.AFormApp
    Dim objAFormFields  As AFORMAUTLib.Fields
    Dim objAFormField   As AFORMAUTLib.Field
     
    '初期値
    Const CON_FILEPATH = "c:¥work¥sample.pdf"
    bEnd = True
     
    'Acrobatオブジェクトの定義&作成
    
    'Acrobat 4,5,6 の時
'    Dim objAcroApp    As Acrobat.CAcroApp
'    Dim objAcroAVDoc  As Acrobat.CAcroAVDoc
'    Dim objAcroPDDoc  As Acrobat.CAcroPDDoc
'    Dim objAcroPDPage As Acrobat.CAcroPDPage
'    Dim objAcroPoint  As Acrobat.CAcroPoint
'    Set objAcroApp   = CreateObject("AcroExch.App")
'    Set objAcroAVDoc = CreateObject("AcroExch.AVDoc")
'    Set objAcroPDDoc = CreateObject("AcroExch.PDDoc")
     
    'Acrobat 7,8,9,10,11 の時
    Dim objAcroApp      As New Acrobat.AcroApp
    Dim objAcroAVDoc    As New Acrobat.AcroAVDoc
    Dim objAcroPDDoc    As New Acrobat.AcroPDDoc
    Dim objAcroPDPage   As Acrobat.AcroPDPage
    Dim objAcroPoint    As Acrobat.AcroPoint
     
    '※CreateObject("AFormAut.App")のエラー
    '※[429 ActiveXコンポーネントはオブジェクトを作成できません。]
    '※回避用 / メモリにAcrobatを強制ロードさせる
    objAcroApp.CloseAllDocs
    
    '処理対象のPDFファイルを開く
    bRet = objAcroAVDoc.Open(CON_FILEPATH, "")
     
    If bRet = False Then
        MsgBox "AVDocオブジェクトはOpen出来ません", _
                vbOKOnly + vbCritical, "処理エラー"
        bEnd = False
        GoTo Skip_AFormAut_Field_TextFont:
    End If
    
    Set objAcroPDDoc = objAcroAVDoc.GetPDDoc
    iPageNum = objAcroPDDoc.GetNumPages
    Set objAFormApp = CreateObject("AFormAut.App")
    Set objAFormFields = objAFormApp.Fields
     
    For i = 0 To iPageNum ― 1
    
        'PDFページサイズを取得
        Set objAcroPDPage = objAcroPDDoc.AcquirePage(i)
        Set objAcroPoint = objAcroPDPage.GetSize
         
        '指定ページにヘッダー用のテキストフィールドを追加
        Set objAFormField = _
            objAFormFields.Add("Header" & (i + 1), "text", _
                i, (objAcroPoint.x / 2100), _
                (objAcroPoint.y ― 15), _
                (objAcroPoint.x / 2 + 100), _
                (objAcroPoint.y ― 35))
         
        'テキストフィールドの各種設定
        With objAFormField
            .SetBackgroundColor "RGB", 1, 1, 1, 0
            .Alignment = "center"
            .TextFont = "HeiseiMin-W3-UniJIS-UCS2-H"
            .Value = "Header " & Now() '表示する文字
            .IsReadOnly = True  '読み込み専用
            .IsHidden = False   '表示
        End With
         
        '設定後に開放
        Set objAFormField = Nothing
        
    Next
     
    'PDFファイルを別名で保存
    sFilePath_new = Replace(CON_FILEPATH, ".pdf", "_new.pdf")
    bRet = objAcroPDDoc.Save(1, sFilePath_new)
    If bRet = False Then
        MsgBox "PDFファイルへ保存出来ませんでした", _
            vbOKOnly + vbCritical, "エラー"
        bEnd = False
    End If
     
    'PDFファイルを閉じる
    bRet = objAcroAVDoc.Close(False)
    If bRet = False Then
        MsgBox "AVDocオブジェクトはClose出来ませんでした", _
                vbOKOnly + vbCritical, "処理エラー"
        bEnd = False
    End If
     
Skip_AFormAut_Field_TextFont:
On Error Resume Next
    '変更しないで閉じます。
    bRet = objAcroAVDoc.Close(False)
     
    'Acrobatアプリケーションの終了
    objAcroApp.Hide
    objAcroApp.Exit
    
    'オブジェクトの開放
    Set objAFormFields = Nothing
    Set objAFormApp = Nothing
    Set objAcroPDPage = Nothing
    Set objAcroPoint = Nothing
    Set objAcroPDDoc = Nothing
    Set objAcroAVDoc = Nothing
    Set objAcroApp = Nothing
     
    If bEnd = True Then
        MsgBox "処理は正常に終了しました。", _
            vbOKOnly + vbInformation, "正常終了"
    End If
    
    Exit Sub
     
'実行エラー(Runtime Error)
Err_AFormAut_Field_TextFont:
    MsgBox Err.Number & vbCrLf & Err.Description, _
            vbOKOnly + vbCritical, "実行時のエラー"
    bEnd = False
    GoTo Skip_AFormAut_Field_TextFont:
End Sub

 

※ソースコードHTML変換:SourceConverter

 

 


 

実行結果

  

Acrobat 7.1.4 実行時の結果

AFormAut : Field.TextFont プロパティ(実行結果)

 

備考

  1. 特に無し。

 

注意

  1. 他の日本語フォントが既に PDFファイル に組み込まれていても使用は出来ません。
    MS-Gothic : MS ゴシック
    MS-Mincho : MS 明朝
    MS-PGothic : MS Pゴシック
    MS-PMincho : MS P明朝
    AFormAut : Field.TextFont プロパティ(フォント) 
  2. Field.Textfont = "MS-Mincho"
    を事項すると 実行エラー(Runtime Error) となる。
    -2147467259 オートメーション エラーです。エラーと特定できません
    AFormAut : Field.TextFont プロパティ(実行エラー)
  3. 更にこの後で強制的に AVDoc.close メソッドを実行すると、
    以下が限りなく表示され、VBAが終了しなくなる。
    別のプログラムでOLEの操作が完了するまで待機を続けます。
    AFormAut : Field.TextFont プロパティ(実行エラー)
  4. 全OLEを実行する前に
    objAcroApp.CloseAllDocs
    で強制的にAcrobat アプリケーションをメモリ上にロードしないと
    Set objAFormApp = CreateObject("AFormAut.App")
    で実行エラー(ランタイムエラー)が発生する場合があります。
    429 ActiveXコンポーネントはオブジェクトを作成できません。
    429 ActiveXコンポーネントはオブジェクトを作成できません。

 

動作確認の環境

  • Acrobat 4.0 + Office 2000
    +  Windows98SE( + WindowsUpdate)
  • Acrobat 5.0.5 + Office 2003( + SP3)
    +  WindowsXP Pro( + SP3 + WindowsUpdate)
  • Acrobat 6.0.6 Pro + Office 2003( + SP3)
    +  WindowsXP Pro( + SP3 + WindowsUpdate)
  • Acrobat 7.1.4 Pro + Office 2003( + SP3)
    +  WindowsXP Pro( + SP2 + WindowsUpdate)
  • Acrobat 8.3.1 Pro + Office 2003( + SP3)
    +  WindowsXP Pro( + SP3 + WindowsUpdate)
  • Acrobat 9.5.2 Extended + Office 2003( + SP3)
    +  WindowsXP Pro( + SP3 + WindowsUpdate)
  • Acrobat X (10.1.4) Extended + Office 2003( + SP3) 
    + WindowsXP Pro( + SP3 + WindowsUpdate)
  • Acrobat XI (11.0) Extended + Office 2003( + SP3)
    + WindowsXP Pro( + SP3 + WindowsUpdate)

 

Adobe Web 解説 URL(英語)

v10.0

http://livedocs.adobe.com/acrobat_sdk/10/Acrobat10_HTMLHelp/IAC_API_FormsIntro.107.37.html

 

戻る

コメントを残す

メールアドレスが公開されることはありません。 * が付いている欄は必須項目です

CAPTCHA


出来るだけ早く返答する様には心がけています。
が、遅くなる時もありますのでご了承ください。


SAMURAI Plugin

コメントをする時は出来れば以下もお願いします。

  • OS名 バージョン
  • Acrobat バージョン
  • ツール(Excel等) バージョン
コメントにサンプルコードを入れるとエラーになる場合が有ります。その時はコードの前後に <code> ・・・</code> タグを入れてください。

This site uses Akismet to reduce spam. Learn how your comment data is processed.