サンプル:PDFの各ページのサイズをチェックする

TOP > サンプル / 関数 > PDFの各ページのサイズをチェックする      [...]


解説

PDFドキュメントの表紙のサイズと、残りのページザイズ(x,y)が全て同じかチェックする。

全てが縦になっているかのチェックにもなる。

 

サンプル Excel VBA

  • F8キーでステップ実行しながら動作確認出来ます。
  • 参照設定を事前にする。

 

Sub TEST_Check_PageSize()

    Debug.Print "TEST_Check_PageSize:" & Now

    Dim objAcroApp          As New Acrobat.AcroApp
    Dim objAcroAVDoc        As New Acrobat.AcroAVDoc
    Dim objAcroPDDoc        As Acrobat.AcroPDDoc
    Dim objAcroPDPage       As Acrobat.AcroPDPage
    Dim objAcroAVPageView   As Acrobat.AcroAVPageView
    Dim objAcroPoint        As Acrobat.AcroPoint
    Dim lRet                As Long
    Dim j                   As Long
    Dim lPageCnt            As Long
    Dim lErrCnt             As Long
    Dim x                   As Long
    Dim y                   As Long
    
    lErrCnt = 0
    'Acrobatを起動表示する
    lRet = objAcroApp.Show      '(TEST用)
    'PDFドキュメントを開いて表示する。
    lRet = objAcroAVDoc.Open("E:¥Test01.pdf", "")
    Set objAcroAVPageView = objAcroAVDoc.GetAVPageView()
    Set objAcroPDDoc = objAcroAVDoc.GetPDDoc()

    lPageCnt = objAcroPDDoc.GetNumPages - 1
    Debug.Print "全頁数 = " & (lPageCnt + 1)

    For j = 0 To lPageCnt
        lRet = objAcroAVPageView.Goto(j)
        Set objAcroPDPage = objAcroAVPageView.GetPage()
        Set objAcroPoint = objAcroPDPage.GetSize
        If j = 0 Then
            '1ページ目
            x = objAcroPoint.x
            y = objAcroPoint.y
        Else
            If Not (x = objAcroPoint.x) Or _
               Not (y = objAcroPoint.y) Then
               'サイズが違う
               Debug.Print "サイズが異なる頁 = " & j
               lErrCnt = lErrCnt + 1
            End If
        End If
    Next j

    '先頭頁とサイズが違う頁数
    Debug.Print "先頭頁とサイズが違う頁数 = " & lErrCnt

    'PDFファイルを保存しないで閉じる
    lRet = objAcroAVDoc.Close(1)
    'Acrobatを閉じる
'    lRet = objAcroApp.Hide      '(TEST用)
'    lRet = objAcroApp.Exit      '(TEST用)

    'オブジェクトを強制解放する
    Set objAcroPoint = Nothing
    Set objAcroAVPageView = Nothing
    Set objAcroPDPage = Nothing
    Set objAcroPDDoc = Nothing
    Set objAcroAVDoc = Nothing
    Set objAcroApp = Nothing
End Sub

 





 

動作確認環境

  • WindowsXP Pro + SP3 +
    Acrobat 8.1.2 Pro + Office 2003

 

戻る

コメントを残す

メールアドレスが公開されることはありません。 * が付いている欄は必須項目です

CAPTCHA


出来るだけ早く返答する様には心がけています。
が、遅くなる時もありますのでご了承ください。


SAMURAI Plugin

コメントをする時は最低でも以下をお願いします。

  • OS名 バージョン
  • Acrobat バージョン
  • ツール(Excel等) バージョン